home *** CD-ROM | disk | FTP | other *** search
/ Floppyshop 2 / Floppyshop - 2.zip / Floppyshop - 2.iso / art&graf.ix / art-3718 / extendpi / read_me.s < prev   
Text File  |  1993-03-02  |  8KB  |  340 lines
  1. ********************************************************************************
  2. * 
  3. * Have you ever tried to load a PI1 format picture into Deluxe Paint
  4. * and got this error message:
  5. * 
  6. *     'Unable to open file. The
  7. *      file is non-existent or
  8. *      a drive error occurred.'
  9. * 
  10. * even though the picture is there on the screen?  It is possible
  11. * that the palette is incorrect and the last screen line may be
  12. * corrupted.
  13. * 
  14. * If you have this problem, check the length of the file.  Deluxe
  15. * Paint expects a PI1 file to be 32066 bytes long, although many
  16. * other packages can handle PI1s 32034 bytes long.  PicSwitch 0.7
  17. * seems to be fond of this size.
  18. * 
  19. * If your file is 32034 bytes long, this program should solve your
  20. * problem.  If not, then you have my commiserations.  If the file
  21. * is 32034 bytes long and this program doesn't fix things, and the
  22. * problem isn't a disk fault, you could always drop me a line with
  23. * a copy of the file - I'd be interested to see it and I might be
  24. * able to fix it.  (I can't guarantee it though.)
  25. * 
  26. * The missing 32 bytes actually contain information used in colour
  27. * cycling, so are normally zeroes anyway.  This program scans your
  28. * disk for PI1s, PI2s, and PI3s 32034 bytes long, loads them into
  29. * memory, creates a blank colour cycling table and rewrites them
  30. * to disk.  (NB This doesn't require extra disk space as files
  31. * 32034 and 32066 bytes long both use 32 clusters.)
  32. * 
  33. * This program and source code/documentation are completely free
  34. * and are distributed with no strings attached.  However, I do
  35. * assert my right to be identified as the author of this software
  36. * in accordance with the Copyright, Designs and Patents Act 1988.
  37. * 
  38. * If you find this program useful, please let me know.  I don't
  39. * believe in moral blackmail so I won't ask you for anything, but
  40. * a couple of quid, a blank disk or two, picture files, PD or just
  41. * a letter would be equally acceptable, as would recommendations 
  42. * for improvements and future developments.  Whatever you send,
  43. * you're likely to get back:
  44. *
  45. *     A self-extracting archive creator
  46. *
  47. *     Details on how to get 70+ PI1 pictures on a disk, and not
  48. *     have to mess about with an unpacker to display them or work
  49. *    on them.
  50. *
  51. *     Anything interesting that I write between now (2/93) and
  52. *     then.
  53. * 
  54. * Much as I would like to, I cannot accept any responsibility for
  55. * loss or damage, material or notional, caused by the use or misuse
  56. * of this program.  As far as I know, it works as described, but if
  57. * it doesn't, let me know.
  58. * 
  59. * Deluxe Paint is copyright by Artistech Developments 1990 and is
  60. * distributed in the UK by Electronic Arts.
  61. * 
  62. * Write to:
  63. * 
  64. *     Dave Jones,
  65. *     100, Radford Road,
  66. *     Hyson Green,
  67. *     Nottingham,
  68. *     NG7 5FU,
  69. *     ENGLAND
  70. * 
  71. ********************************************************************************
  72. *
  73. * Assembler control directives
  74. *
  75.         output    extendpi.tos
  76.         opt    o1+,o2+,ow-
  77. *
  78. ********************************************************************************
  79. *
  80. * Constants for trap instruction
  81. *
  82. GEMDOS        equ    $01
  83. XBIOS        equ    $0e
  84. *
  85. ********************************************************************************
  86. *
  87. * Constants for GEMDOS functions
  88. *
  89. CRAWCIN        equ    $07
  90. CCONWS        equ    $09
  91. FSETDTA        equ    $1a
  92. FCREATE        equ    $3c
  93. FOPEN        equ    $3d
  94. FCLOSE        equ    $3e
  95. FREAD        equ    $3f
  96. FWRITE        equ    $40
  97. PTERM        equ    $4c
  98. FSFIRST        equ    $4e
  99. FSNEXT        equ    $4f
  100. *
  101. ********************************************************************************
  102. *
  103. * Constants for XBIOS functions
  104. *
  105. CURSCONF    equ    $15
  106. *
  107. ********************************************************************************
  108. *
  109. * Constants for XBIOS $15 - CursConf
  110. *
  111. CURS_OFF    equ    $00
  112. CURS_ON        equ    $01
  113. *
  114. ********************************************************************************
  115. *
  116. * The file sizes involved.  We want to convert short-sized PI?s to
  117. * long-sized ones.
  118. *
  119. SHORT_SIZE    equ    32034
  120. LONG_SIZE    equ    32066
  121. *
  122. *
  123. ********************************************************************************
  124. *
  125. * Macros for frequent functions
  126. *
  127. pstring        MACRO
  128.         pea    \1
  129.         move.w    #CCONWS,-(a7)
  130.         trap    #GEMDOS
  131.         addq.l    #6,a7
  132.         ENDM
  133. *
  134. cursor        MACRO
  135.         move.w    #CURSCONF,-(a7)
  136.         trap    #XBIOS
  137.         addq.l    #4,a7
  138.         ENDM
  139. *
  140. getkey        MACRO
  141.         move.w    #CRAWCIN,-(a7)
  142.         trap    #GEMDOS
  143.         addq.l    #2,a7
  144.         ENDM
  145. *
  146. ********************************************************************************
  147. *
  148. * Code starts here
  149. *
  150. ********************************************************************************
  151.  
  152. start        * no error yet
  153.         clr.w    return_code
  154.  
  155.         * hide cursor
  156.         move.w    #CURS_OFF,-(a7)
  157.         cursor
  158.  
  159.         * say hello
  160.         pstring    banner
  161.         getkey
  162.  
  163.         cmp.b    #' ',d0        space continues
  164.         bne    exit        anything else exits
  165.  
  166.         * set dta
  167.         pea    dta        our buffer
  168.         move.w    #FSETDTA,-(a7)
  169.         trap    #GEMDOS
  170.         addq.l    #6,a7
  171.  
  172.         * find first
  173.         clr.w    -(a7)        normal file r/w
  174.         pea    file_spec    *.PI?
  175.         move.w    #FSFIRST,-(a7)
  176.         trap    #GEMDOS
  177.         addq.l    #8,a7
  178.  
  179.         tst.l    d0        -ve = no files
  180.         bmi    no_files
  181.  
  182. loop        * check size
  183.         cmpi.l    #SHORT_SIZE,size
  184.         bne    skip
  185.  
  186.         * display file name
  187.         pstring    process
  188.         pstring    name
  189.  
  190.         * read file
  191.         clr.w    -(a7)
  192.         pea    name
  193.         move.w    #FOPEN,-(a7)
  194.         trap    #GEMDOS
  195.         addq.l    #8,a7
  196.  
  197.         tst.l    d0
  198.         bmi    error
  199.  
  200.         move.w    d0,-(a7)    put handle on stack for later
  201.  
  202.         pea    buffer
  203.         pea    SHORT_SIZE
  204.         move.w    d0,-(a7)
  205.         move.w    #FREAD,-(a7)
  206.         trap    #GEMDOS
  207.         lea    12(a7),a7
  208.  
  209.         tst.l    d0
  210.         bmi    error
  211.  
  212.         move.w    #FCLOSE,-(a7)    handle's there already
  213.         trap    #GEMDOS
  214.         addq.l    #4,a7
  215.  
  216.         tst.l    d0
  217.         bmi    error
  218.  
  219.         * clear end
  220.         lea    buffer+SHORT_SIZE,a0
  221.         moveq    #LONG_SIZE-SHORT_SIZE-1,d0
  222. clear        clr.b    (a0)+
  223.         dbf    d0,clear
  224.  
  225.         * write file
  226.         clr.w    -(a7)
  227.         pea    name
  228.         move.w    #FCREATE,-(a7)
  229.         trap    #GEMDOS
  230.         addq.l    #8,a7
  231.  
  232.         tst.l    d0
  233.         bmi    error
  234.  
  235.         move.w    d0,-(a7)    put handle on stack for later
  236.  
  237.         pea    buffer
  238.         pea    LONG_SIZE
  239.         move.w    d0,-(a7)
  240.         move.w    #FWRITE,-(a7)
  241.         trap    #GEMDOS
  242.         lea    12(a7),a7
  243.  
  244.         tst.l    d0
  245.         bmi.s    error
  246.  
  247.         move.w    #FCLOSE,-(a7)    handle's there already
  248.         trap    #GEMDOS
  249.         addq.l    #4,a7
  250.  
  251.         tst.l    d0
  252.         bmi.s    error
  253.  
  254.         pstring    done
  255.  
  256. skip        * find next
  257.         move.w    #FSNEXT,-(a7)
  258.         trap    #GEMDOS
  259.         addq.l    #2,a7
  260.  
  261.         tst.l    d0
  262.         bmi.s    no_more_files
  263.  
  264.         bra    loop
  265.  
  266. no_files    pstring    empty
  267.         bra.s    exit
  268.  
  269. no_more_files    pstring    more            fall through to exit
  270.  
  271. exit        pstring    end_message
  272.         getkey
  273.  
  274.         * show cursor
  275.         move.w    #CURS_ON,-(a7)
  276.         cursor
  277.  
  278.         move.w    return_code,-(a7)    error code (if any)
  279.         move.w    #PTERM,-(a7)
  280.         trap    #GEMDOS
  281.  
  282. error        move.w    d0,return_code
  283.         pstring    error_msg
  284.         bra.s    exit
  285.  
  286.  
  287. file_spec    dc.b    "*.pi?",0
  288.  
  289. banner        dc.b    $1b,"E"
  290.         dc.b    "Extend PI1-3 files - ZZD '93"
  291.         dc.b    $0d,$0a
  292.         dc.b    "~~~~~~~~~~~~~~~~~~~~~~~~~~~~"
  293.         dc.b    $0d,$0a
  294.         dc.b    $0d,$0a
  295.         dc.b    "Space to continue, any other key to exit"
  296.         dc.b    $0d,$0a
  297.         dc.b    $0d,$0a
  298.         dc.b    0
  299.  
  300. empty        dc.b    "There are no PI? files in this directory"
  301.         dc.b    $0d,$0a
  302.         dc.b    0
  303.  
  304. more        dc.b    $0d,$0a
  305.         dc.b    "All files processed"
  306.         dc.b    $0d,$0a
  307.         dc.b    0
  308.  
  309. process        dc.b    "Processing "
  310.         dc.b    0
  311.  
  312. done        dc.b    " - done"
  313.         dc.b    $0d,$0a
  314.         dc.b    0
  315.  
  316.  
  317. end_message    dc.b    $0d,$0a
  318.         dc.b    "Press any key to exit"
  319.         dc.b    $0d,$0a
  320.         dc.b    0
  321.  
  322. error_msg    dc.b    $0d,$0a
  323.         dc.b    "A fatal error has occurred"
  324.         dc.b    $0d,$0a
  325.         dc.b    0
  326.  
  327.         even
  328.         bss
  329.  
  330. dta
  331. reserved    ds.b    21        reserved for GEM
  332. attribute    ds.b    1
  333. time        ds.b    2        time and
  334. date        ds.b    2        date of file creation
  335. size        ds.b    4        file length (long)
  336. name        ds.b    14        file name
  337.  
  338. return_code    ds.w    1
  339. buffer        ds.w    16033
  340.